phononnumber

◼ phononnumber[Nph] returns the phonon number operator in the bra-ket representation. Nph is the phonon number cutoff.

◼ See also: phononplus, phononminus, phononx, transformtoPH.

Further examples

Load sneg and declare some quantities.

<< sneg`sneg`;
snegfermionoperators[c];
snegrealconstants[t, g, ω];

Check definition

phononnumber[0]
phononnumber[1]
phononnumber[2]
phononnumber[3]

Construct a basis for two lattice sites and one phonon mode. We are interested in the subspace with a single electron, i.e. (Q, (Subscript[S, z])) = (-1, 1/2).

bz0 = qsbasisvc[{c[1], c[2]}];
MatrixForm[bz0]
Nph = 5;
bz = transformtoPHvc[bz0, Nph];
states = Select[bz, First[#] == {-1, 1/2} &][[1, 
          2]]

Hopping Hamiltonian where the phonon displacement modulates the hopping amplitude. Check that site interchange (parity) is a good quantum number.

H = -t nc[1 + g phononx[Nph],  
              hop[c[1], c[2]]] + ω phononnumber[
              Nph];
lr = lrmap[{c[1], c[2]}]
lr = Join[lr, conj[lr]]
H == (H /. lr) // ExpandAll

Calculate eigenstates

mat = matrixrepresentationvc[H, states];
MatrixForm[mat]
parameters = {t -> 1, 
          g -> 0.1, ω -> 0.5};
eig = 
        Sort @ Transpose @ 
            Eigensystem[mat /. parameters];
(Subscript[eig, [[All, 1]]])

Separately diagonalize the subspace with even parity

bzlr = 
        transformtoLRvc[bzvc2bzop[bz], {c[1], c[2]}, 
          vacuum[]];
states1 = Select[bzlr, 
            First[#] == {-1, 1/2, 1} &][[1, 
          2]];
mat1 = 
        matrixrepresentationvc[H, states1];
eig1 = 
        Sort @ Transpose @ 
            Eigensystem[mat1 /. parameters];

Lowest energy states in the even parity sector

eig1[[1, 2]] states1

eig1[[2, 2]] states1

Odd parity sector

states2 = Select[bzlr, 
            First[#] == {-1, 
                  1/2, -1} &][[1, 
          2]];
mat2 = 
        matrixrepresentationvc[H, states2];
eig2 = 
        Sort @ Transpose @ 
            Eigensystem[mat2 /. parameters];

eig2[[1, 2]] states2

eig2[[2, 2]] states2

Difference in energy is 2t=2 even in the presence of electron-phonon coupling.

eig1[[1, 1]] - eig2[[1, 1]]